package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.utils.Timer;
	import flash.display.Shape;
	
	public class dotbox extends Sprite
	{

		private var sw:uint=stage.stageWidth
		private var sh:uint=stage.stageHeight
		
		private var dots:Array
		private var screen:Shape
		
		private var focal:uint=170		

		private var fpsTF:TextField
		private var fps:uint=0
	
		private var detail:uint
		private var space:uint
		private var center:Number
		private var color:Number
		
		
		public function dotbox():void
		{
			stage.scaleMode="noScale"
			//
			addChild(screen=new Shape())
			screen.x=sw/2
			screen.y=sh/2
			//
			fpsTF=new TextField()
			fpsTF.selectable=false
			fpsTF.defaultTextFormat=new TextFormat("verdana",10)
			addChild(fpsTF)
			flash.utils.setInterval(fpsInterval, 1000);
			stage.addEventListener("enterFrame",fpsEnterFrame)			
			//
			dots=[]
			detail=10
			space=7
			center=detail*space/2
			color=0xff/detail
			//
			for (var x:Number=0;x<detail;x++)
				for (var y:Number=0;y<detail;y++)
					for (var z:Number=0;z<detail;z++){
						var i:Number=dots.push([x*space-center,y*space-center,z*space-center])
						dots[i-1].color=(color*x)+(color*y<<8)+(color*z<<16)
					}						
			//
			stage.addEventListener("enterFrame",render)
			stage.addEventListener("mouseWheel",wheel)
			stage.addEventListener("click",toggleFullScreen)
		}
		
		private function wheel(...e):void{focal=Math.min(Math.max(focal+=e[0].delta,50),200)}
		
		private function toggleFullScreen(...e):void{stage.displayState=(stage.displayState=='normal')?"fullScreen":"normal"}
		
		private function drag():void
		{
			rotate("Y",(stage.mouseX-sw/2)/1000)
			rotate("X",(stage.mouseY-sh/2)/-1000)
		}

// FPS

		private function fpsInterval():void{fpsTF.text=fps+" fps";fps=0}
		private function fpsEnterFrame(...e):void{fps++}
		
// 3D

		private function mXm(m1:Array,m2:Array):Array
		{
			if(m1[0].length==m2.length){var r:Array=[]
				for(var i:uint=0;i<m1.length;i++){r[i]=[]
					for(var j:uint=0;j<m2[0].length;j++){r[i][j]=0
						for(var k:uint=0;k<m2.length;k++){
							r[i][j]+=m1[i][k]*m2[k][j]
						}
					}
				} return r
			} else{ trace("ERROR : mXm "+m1[0].length+" != "+m2.length); return null}
		}
	
		private var tm:Array
		
		private function rtm(m:Array):void{if(tm){tm=mXm(tm,m)}else tm=m}
		
		private function rotate(i:String,a:Number):void
		{
			var sin:Number = Math.sin(a)
			var cos:Number = Math.cos(a)
			switch(i){
				case "X" : {rtm([[1,0,0],[0,cos,sin],[0,-sin,cos]]);break}
				case "Y" : {rtm([[cos,0,-sin],[0,1,0],[sin,0,cos]]);break}
				case "Z" : {rtm([[cos,sin,0],[-sin,cos,0],[0,0,1]]);break}
			}
		}
		
		private function render(...e):void
		{
			var g:Array=[].concat(dots)
			
			drag()
			screen.graphics.clear()

			if(tm) for (var d:uint=0;d<dots.length;d++) {
				g[d]=mXm([dots[d]],tm)[0]
				g[d].z=g[d][2]
				g[d].color=dots[d].color
			}

//			g.sortOn([2],Array.NUMERIC) // crash @ fp9
			g.sortOn(["z"],Array.NUMERIC)
			
			for (var c:uint=0;c<g.length;c++){
				if(g[c][2]/focal<1)
				{
					var s:Number=focal/(focal-g[c][2])
					//
					var x:Number=g[c][0]*s*2
					var y:Number=g[c][1]*s*2
					//
					screen.graphics.beginFill(g[c].color)
					screen.graphics.drawCircle(x,y,Math.max(g[c][2]/4,2))
				}
			}
		}		
	}
}